Skripti http://oppe.admin.ut.ee/ained/tulemus/oppetool.asp kood
VÄRVIDE TÄHENDUSED
|
Serveripoolne skript
|
|
Kliendipoolne skript
|
|
Link
|
|
Include-lause
|
|
Freimid
|
|
Kommentaarid
|
|
Objekti link
|
|
HTML ja tavaline tekst
|
<%
'Tartu Ülikooli õppeaineregistri WWW-liides
'Autor: Aulis Sibola
'Juhendaja: Jaanus Pöial
'Õppetoolide väljastus.
'Õppetoolid grupeeritakse instituutide kaupa.
'Kui instituudil/õppetoolil on antud aadress/telefon, siis
'väljastatakse ka need.
'Siit suundutakse õppetooli ainete loetellu.
%>
<!--#INCLUDE file="header.lisamine"-->
<%
'Kui teaduskonda pole küsitud, suunatakse teaduskondade loetellu:
if Request("TK") = "" then
Response.Redirect "algus.asp#oppetool"
end if
%>
<%
'Avame ühenduse ODBC-ga:
Set objekt = Server.CreateObject("ADODB.Connection")
'Avame andmebaasi:
objekt.Open "Aineregister"
'Teaduskonna nime küsimine
'Päring andmebaasis:
Paring = "select nimi from dba_teaduskond where kood = '" & Request("TK") & "'"
set querteaduskond = objekt.Execute(Paring)
'Kui sellist teaduskonda ei leidu, suundutakse pealehele tagasi:
if querteaduskond.EOF then
'Viisakas sulgemine:
querteaduskond.close
Response.Redirect "algus.asp#oppetool"
'Kui teaduskond leidub, siis tiitlisse paigutamiseks asendatakse ¯(z~) z~-ga:
else
teadkond=replace(querteaduskond("nimi"),"¯","z~")
'Kuna rohkem seda vaja pole, siis päring suletakse:
querteaduskond.close
end if 'if querteaduskond.EOF
%>
<HTML><HEAD>
<title><%=teadkond%></title>
</HEAD>
<!--#INCLUDE file="body.htm"-->
<%
'Õppetoolide nimekirja saamine:
'Andmebaasist võetakse instituudid ja õppetoolid, kus teaduskond on küsitu:
'Päring andmebaasis:
Paring = "SELECT DBA_Instituut.nimi as instit, " & _
"DBA_Instituut.kood as inskood, " & _
"dba_oppetool.nimi as oppet, " & _
"dba_oppetool.kood as oppekood, " & _
"dba_oppetool.teaduskond, " & _
"dba_instituut.aadress as insaadr, " & _
"dba_instituut.telefon as instel, " & _
"dba_oppetool.aadress, dba_oppetool.telefon " & _
"FROM DBA_Instituut, dba_oppetool " & _
"where dba_instituut.kood=dba_oppetool.instituut " & _
"and DBA_oppetool.teaduskond = '" & Request("TK") & "' and " & _
"dba_instituut.teaduskond = '" & Request("TK") & "'" & _
"order by dba_instituut.kood, dba_oppetool.kood"
set queroppetool = objekt.Execute(Paring)
'Kui õppetoole pole, tuleb tagasi saata:
if queroppetool.EOF then
Response.Write "<h2>Teie poolt valitud teaduskonnas pole õppetoole."
Response.Write "Parim lahendus on valida uus <a href=algus.asp#oppetool>teaduskond</a>.</h2>"
'Kui on õppetoole, väljastatakse valiku teade:
else
Response.Write "<center><h2>Valige alljärgnevaist õppetool, mille aineid soovite näna:</h2></center>"
end if 'if
'Et mingit grupeerimist luua, kasutatakse html-elementi <dl>
Response.Write vbNewLine & "<dl>" & vbNewLine
'Et grupeerimist teha, võetakse kasutusele järgnevad muutujad:
eelmins = "" 'Eelmise instituudi kontrollimiseks
esimene = true 'Andmaks teada, et esimene väli on veel olemata
'Väljastatakse kuni leidub õppetoole:
Do While Not queroppetool.EOF
'Instituudi vahetuse kontroll:
if eelmins <> queroppetool("instit") then
eelmins = queroppetool("instit")
'Esimese instituudi korral pole vaja <dl>-i ära lõpetada
if esimene then
esimene = false
else
Response.Write "</dl>" & vbNewLine
end if
'Instituudi väljastus:
Response.Write "<dt>" & queroppetool("instit") & " <" & queroppetool("inskood") & ">"
'Aadressi ja telefoni väljastus:
if queroppetool("insaadr") <> "" and queroppetool("instel") <> "" then
Response.Write " (" & queroppetool("insaadr") & ", telefon: " & queroppetool("instel") & ")"
elseif queroppetool("insaadr") <> "" then
Response.Write " (" & queroppetool("insaadr") & ")"
elseif queroppetool("instel") <> "" then
Response.Write " (telefon: " & queroppetool("instel") & ")"
end if
'Õppetoolide alguses on 'dl':
Response.Write "</dt>" & vbNewLine & "<dl>" & vbNewLine
end if
'Õppetooli väljastus:
Response.Write "<dt><a href=nimekiri.asp?TK=" & queroppetool("teaduskond")
Response.Write "&INS=" & queroppetool("inskood")
Response.Write "&OT=" & queroppetool("oppekood") & ">"
Response.Write queroppetool("oppet") & " ("
Response.Write queroppetool("oppekood") & ")</a></dt>" & vbNewLine
'Õppetooli aadressi ja telefoni väljastus:
if queroppetool("aadress") <> "" and queroppetool("telefon") <> "" then
Response.Write "<dl><dt>" & queroppetool("aadress") & ", telefon: "
Response.Write queroppetool("telefon") & "</dl></dt>" & vbNewLine
elseif queroppetool("aadress") <> "" then
Response.Write "<dl><dt>" & queroppetool("aadress") & "</dl></dt>" & vbNewLine
elseif queroppetool("telefon") <> "" then
Response.Write "<dl><dt>telefon: " & queroppetool("telefon") & "</dl></dt>" & vbNewLine
end if
'Järgmine väli:
queroppetool.movenext
Loop 'Tsükli lõpp
'Päringu sulgemine:
queroppetool.close
'Ühenduse sulgemine:
objekt.close
'Korralik lõpetus:
Response.Write "</dl>" & vbNewLine & "</dl>" & vbNewLine
%>
<!--#INCLUDE file="footer.htm"-->