Skripti http://oppe.admin.ut.ee/ained/tulemus/algus.asp kood
VÄRVIDE TÄHENDUSED
|
Serveripoolne skript
|
|
Kliendipoolne skript
|
|
Link
|
|
Include-lause
|
|
Freimid
|
|
Kommentaarid
|
|
Objekti link
|
|
HTML ja tavaline tekst
|
<%
'Tartu Ülikooli õppeaineregistri WWW-liides
'Autor: Aulis Sibola
'Juhendaja: Jaanus Pöial
'Otsingute pealeht.
'Andmebaasist: teaduskondade, õppekavade, astmete ja keelte loetelu.
'Siit suundutakse kõikidesse otsingutesse
'Andmebaasiga ühenduseks kasutatakse ODBC-d (ühendus luuakse läbi ADO).
%>
<!--#INCLUDE file="header.lisamine"-->
<HTML>
<HEAD>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=iso-8859-1">
<META NAME="Author" CONTENT="Aulis Sibola">
<TITLE>TÜ Õppeaineregister</TITLE>
</HEAD>
<!--#INCLUDE file="body.htm"-->
<!--#INCLUDE virtual="/Misc/table.htm"-->
<CENTER>
<IMG SRC="/Gifs/Aineregister.gif" ALT="Õppeaineregister">
</CENTER>
<UL>
<LI>
<A NAME="oppetool"></A>
<form action=oppetool.asp method=post>
<FONT COLOR="#008000" SIZE=+3>Otsite konkreetse
<A HREF="juhend.asp#oppetooli jargi">õppetooli</A> aineid?</FONT>
<BR>
<FONT SIZE=+2 COLOR="#800040">Valige teaduskond:</FONT>
<select name=TK>
<%
'Andmebaasist andmete saamiseks luuakse ODBC-ühendus andmebaasiga.
'Selleks kasutatakse ADODB-ühendusviisi.
'Ühenduse loomine:
Set yhendus = Server.CreateObject("ADODB.Connection")
'Andmebaasi avamine:
yhendus.Open "Aineregister"
'Teaduskondade nimekirja leidmine andmebaasist.
'Päring:
Set teaduskond = yhendus.Execute("select nimi, kood from dba_teaduskond order by jarjestus")
'Väljastatakse, kuni on andmeid:
'Iga teaduskonna korral väljastatakse see menüüsse.
do while not teaduskond.EOF
%><option value=<%=teaduskond("kood")%>><%=teaduskond("nimi")%>
<%teaduskond.MoveNext
loop 'do while not...
'Teaduskondade sulgemine:
teaduskond.close
%>
</select>
<FONT SIZE=+2 COLOR="#800040"><br>ja suunduge edasi:</FONT>
<input type=image SRC="/Gifs/Nool.gif" ALT="õppetoolide loetellu" BORDER=0 align=abscenter>
</form>
<LI>
<A NAME="ainenimi"></A>
<FORM action=nimi.asp method=post>
<FONT COLOR="#008000" SIZE=+3>Teate õppeaine
<A HREF="juhend.asp#nimiteada">nime</A>?</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Sisestage aine nimi siia:</FONT>
<BR>
<INPUT name=nimi size=60>
<BR>
<FONT COLOR="#800040" SIZE=+2>Mida otsida?
<SELECT name=suur>
<OPTION selected>alamstringi
<OPTION>täpset nime
</SELECT>
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Sorteerida ainete nimed
<A HREF="juhend.asp#tahestik">tähestiku järgi</A>
<INPUT type=checkbox name=tahestik value=OK>.<br>
Väljastada ained, mis toimuvad
<a href=juhend.asp#oppeaasta>sel õppeaastal</a>
<input type=checkbox name=selaastal value=OK>.
</FONT>
<BR>
<INPUT type=submit value="Otsima!"><INPUT type=reset value="Esialgne seis">
</FORM>
<LI>
<A NAME="ainekood"></A>
<FORM action=aine.asp method=get>
<FONT COLOR="#008000" SIZE=+3>Teate
õppeaine <A HREF="juhend.asp#koodteada">koodi</A>?</FONT>
<BR><FONT COLOR="#800040" SIZE=+2>Sisestage see siia:</FONT>
<BR><INPUT name=aine size=15>
<BR><INPUT type=submit value="Otsima!"><INPUT type=reset value="Esialgne seis"></FORM>
<LI>
<A NAME="oppejoud"></A>
<FORM action=oppejoud.asp method=post>
<FONT COLOR="#008000" SIZE=+3>Teate
ainet lugeva
<A HREF="juhend.asp#lugeja">õppejõu nime</A>?</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Eesnimi: <INPUT name=eesnimi size=20></FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Perekonnanimi: <INPUT name=perenimi size=30></FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Täpsustage infot: <SELECT name=otsing>
<OPTION value=eesnimi>sisestasite õppejõu eesnime
<OPTION value=perenimi>sisestasite õppejõu perekonnanime
<OPTION value=eesjapere selected>sisestasite nii ees- kui perekonnanime
<OPTION value=eesnimeosa>sisestasite osa eesnimest
<OPTION value=perenimeosa>sisestasite osa perekonnanimest
<OPTION value=eespereosa>sisestasite mingi osa ees ja perekonnanimest
</SELECT></FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Sorteerida ainete nimed
<A HREF="juhend.asp#tahestik">tähestiku
järgi</A> <INPUT type=checkbox name=tahestik value=OK>.<br>
Väljastada ained, mis toimuvad
<a href=juhend.asp#oppeaasta>sel õppeaastal</a>
<input type=checkbox name=selaastal value=OK>.
</FONT>
<BR>
<INPUT type=submit value="Otsima!"><INPUT type=reset value="Esialgne seis">
</FORM>
<LI>
<A NAME="oppekava"></A>
<FORM action=oppekava.asp method=post>
<FONT COLOR="#008000" SIZE=+3>Teate
<A HREF="juhend.asp#oppekava">õppekava</A>, millesse aine(d) kuulub(vad)?</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>
Õppekava: <select name=oppekava>
<%
'Õppekavade nimekirja leidmine andmebaasist
'Päringuks kutsutakse välja andmebaasisisene päring:
Set kavad = yhendus.Execute("{Call oppkavanimekiri}")
'Väljastus, kuni õppekavasid leidub:
'Õppekavad pannakse menüüsse.
do while not kavad.EOF
Response.Write "<option>" & kavad("oppekava") & vbNewLine
kavad.MoveNext
loop 'do while not...
'Õppekavade päringu sulgemine:
kavad.close
%>
</select>
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Aste: <SELECT name=aste>
<%
'Astmete leidmine andmebaasist
'Astmetel on baasisisene kirjutusviis ja lisaväljal on
'väljastuseks vajalik kirjutusviis.
'Päring:
Set aste = yhendus.Execute("select nimi, kirjapilt from DBA_aste order by kood")
'Astmed väljastatakse menüüsse:
'Kui aste on tühik ( ), siis väljastatakse menüüsse tühik ja märgitakse
'see valituks.
do while not aste.EOF
if aste("nimi") = " " then
Response.Write "<option value=' ' selected>"
else
Response.Write "<option value=" & aste("nimi") & ">"
end if
Response.Write aste("kirjapilt") & vbNewLine
aste.MoveNext
loop 'do while not...
'Astmete päringu sulgemine:
aste.close
%>
</SELECT>
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Väljastada <SELECT name=otsing>
<OPTION value=kavajaaste>õppekava ja astme
<OPTION value=kava selected>õppekava
<OPTION value=aste>kõikide õppekavade selle astme
</SELECT> ained.
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Mis ained väljastada? <SELECT name=kohus>
<OPTION value=molemad>nii kohustuslikud kui valikained
<OPTION value=koh>kohustuslikud ained
<OPTION value=val>valikained
</SELECT>
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Sorteerida ainete nimed <A HREF="juhend.asp#tahestik">tähestiku
järgi</A> <INPUT type=checkbox name=tahestik value=OK>.<br>
Väljastada ained, mis toimuvad <a href=juhend.asp#oppeaasta>sel õppeaastal</a>
<input type=checkbox name=selaastal value=OK>.
</FONT>
<BR>
<INPUT type=submit value="Otsima!"><INPUT type=reset value="Esialgne seis">
</FORM>
<LI>
<A NAME="keel"></A>
<FORM action=keeled.asp method=post>
<FONT COLOR="#008000" SIZE=+3>Soovite
näha konkreetses
<A HREF="juhend.asp#oppekeel">keeles</A> loetavaid aineid?</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>
Õppekeel: <select name=keel>
<%
'Õppekeelte leidmine andmebaasist
'Päring:
Set keeled = yhendus.Execute("select nimi from Keeled order by nimi")
'Keeled väljastatakse menüüsse:
'Inglise keel märgitakse valituks.
do while not keeled.EOF
if keeled("nimi") = "inglise" then
Response.Write "<option selected>"
else
Response.Write "<option>"
end if
Response.Write keeled("nimi") & vbNewLine
keeled.MoveNext
loop 'do while not...
'Keelte päringu sulgemine:
keeled.close
'Ühenduse sulgemine andmebaasiga:
yhendus.close
%>
</select>
</FONT>
<BR>
<FONT COLOR="#800040" SIZE=+2>Sorteerida ainete nimed
<A HREF="juhend.asp#tahestik">tähestiku
järgi</A> <INPUT type=checkbox name=tahestik value=OK>.<br>
Väljastada ained, mis toimuvad
<a href=juhend.asp#oppeaasta>sel õppeaastal</a>
<input type=checkbox name=selaastal value=OK>.
</FONT>
<BR>
<INPUT type=submit value="Otsima!"><INPUT type=reset value="Esialgne seis">
</FORM>
<li>
<FONT COLOR="#008000" SIZE=+3>Soovite
enamust ülaltoodud võimalustest <a href=juhend.asp#komplex>korraga kasutada</a>?</FONT>
<br>
<FONT COLOR="#800040" SIZE=+2>
Siirduge edasi: </font>
<a href=komplex.asp><img src=/Gifs/nool.gif alt=" komplekspäringusse " border=0 align=abscenter></a>
</UL>
<p>
<!--#INCLUDE virtual="/Misc/table.htm"-->
<!--#INCLUDE file="footer.htm"-->